1С:Предприятие предоставляет возможность в запросах разыменовывать ссылочные поля, т.е. обращаться к подчиненным полям «через точку». Очень удобная возможность, которая позволяет упростить текст запроса. Но следует понимать каким образом в платформе реализован данный функционал и чем он опасен. Разберемся более подробно.
При обращении к подчиненному полю «через точку» происходит неявное соединение с таблицей этого типа. Например, обращение в запросе
ВЫБРАТЬ
ЗаказыКлиентовОстатки.Номенклатура.Артикул,
ЗаказыКлиентовОстатки.ЗаказаноОстаток
ИЗ
РегистрНакопления.ЗаказыКлиентов.Остатки КАК ЗаказыКлиентовОстатки
Приведет к неявному соединению с таблицей справочника Номенклатура, а реальный запрос, который будет выполняться к базе будет аналогичен этому:
ВЫБРАТЬ
СпрНоменклатура.Артикул,
ЗаказыКлиентовОстатки.ЗаказаноОстаток
ИЗ
РегистрНакопления.ЗаказыКлиентов.Остатки КАК ЗаказыКлиентовОстатки
ЛЕВОЕ СОЕДИНЕНИЕ Справочник.Номенклатура КАК СпрНоменклатура
ПО ЗаказыКлиентовОстатки.Номенклатура = СпрНоменклатура.Ссылка
На первый взгляд все корректно и правильно, но как система поведет себя, когда разыменовывается поле составного типа? Система будет соединяться СО ВСЕМИ таблицами, входящими в составной тип! Т.е. запрос
ВЫБРАТЬ
ЦеныНоменклатурыПоставщиков.Регистратор.Номер,
ЦеныНоменклатурыПоставщиков.Цена
ИЗ
РегистрСведений.ЦеныНоменклатурыПоставщиков КАК ЦеныНоменклатурыПоставщиков
будет преобразован во что-то вроде:
ВЫБРАТЬ
ВЫБОР
КОГДА ЦеныНоменклатурыПоставщиков.Регистратор ССЫЛКА Документ.ЗаказПоставщику
ТОГДА ДокЗаказПоставщику.Номер
КОГДА ЦеныНоменклатурыПоставщиков.Регистратор ССЫЛКА Документ.КорректировкаРегистров
ТОГДА ДокКорректировкаРегистров.Номер
КОГДА ЦеныНоменклатурыПоставщиков.Регистратор ССЫЛКА Документ.ПоступлениеТоваровУслуг
ТОГДА ДокПоступлениеТоваровУслуг.Номер
КОГДА ЦеныНоменклатурыПоставщиков.Регистратор ССЫЛКА Документ.РегистрацияЦенНоменклатурыПоставщика
ТОГДА ДокРегистрацияЦенНоменклатурыПоставщика.Номер
КОНЕЦ КАК Номер,
ЦеныНоменклатурыПоставщиков.Цена
ИЗ
РегистрСведений.ЦеныНоменклатурыПоставщиков КАК ЦеныНоменклатурыПоставщиков
ЛЕВОЕ СОЕДИНЕНИЕ Документ.ЗаказПоставщику КАК ДокЗаказПоставщику
ПО ЦеныНоменклатурыПоставщиков.Регистратор = ДокЗаказПоставщику.Ссылка
ЛЕВОЕ СОЕДИНЕНИЕ Документ.КорректировкаРегистров КАК ДокКорректировкаРегистров
ПО ЦеныНоменклатурыПоставщиков.Регистратор = ДокКорректировкаРегистров.Ссылка
ЛЕВОЕ СОЕДИНЕНИЕ Документ.ПоступлениеТоваровУслуг КАК ДокПоступлениеТоваровУслуг
ПО ЦеныНоменклатурыПоставщиков.Регистратор = ДокПоступлениеТоваровУслуг.Ссылка
ЛЕВОЕ СОЕДИНЕНИЕ Документ.РегистрацияЦенНоменклатурыПоставщика КАК ДокРегистрацияЦенНоменклатурыПоставщика
ПО ЦеныНоменклатурыПоставщиков.Регистратор = ДокРегистрацияЦенНоменклатурыПоставщика.Ссылка
И ко всей этой конструкции будут добавлены ограничения на уровне записей (RLS), если они используются. Все это может существенно замедлить выполнение запроса.
Иногда при написании запроса известно какая ссылка будет находиться в поле составного типа. В этом случае правильно привести составной тип к одному необходимому и избежать соединения со всеми таблицами составного типа. Для приведения составного типа к какому-то одному используется оператор
Выразить(<Выражение> КАК <Тип значения>)
Параметр <Выражение> можно привести к ссылочному типу или к одному из примитивных типов.
Если <Выражение> содержит в составном типе требуемый <Тип значения>, то приведение типа считается осуществимым, и для каждого значения указанного типа результатом будет это самое значение. Для значений других типов результатом приведения типа будет значение NULL.
Если <Выражение> не содержит в составном типе требуемый <Тип значения>, то выполнение данного запроса завершится ошибкой.
Пример использования оператора Выразить, когда известно какая ссылка будет находиться в поле составного типа:
ВЫБРАТЬ
ВЫРАЗИТЬ(ЦеныНоменклатурыПоставщиков.Регистратор КАК Документ.ЗаказПоставщику).Номер КАК Номер,
ЦеныНоменклатурыПоставщиков.Цена
ИЗ
РегистрСведений.ЦеныНоменклатурыПоставщиков КАК ЦеныНоменклатурыПоставщиков
ГДЕ
ЦеныНоменклатурыПоставщиков.Регистратор ССЫЛКА Документ.ЗаказПоставщику
В запросе выше пожертвовали компактностью получения поля Номер ради производительности. В результате текст запроса получился более громоздким, но запрос выполнится быстрее за счет того, что не будет лишних ненужных соединений со всеми таблицами составного поля Регистратор.
